Cargador avanzado de Flash

Con Flash hay la instrucción loadMovie para cargar una película dentro de la película actual. Esta instrucción admite tanto ficheros de Flash ".swf", como fotos ".jpg". Pero existe algo mejor que el loadMovie que nos permite un mayor control sobre la carga de la película.

Es posible hacer que el cargador se encuentre en la película madre y no en la película que se va a cargar. De esta forma no debería haber problemas para hacer un cargador de fotos.

Para conseguir nuestro objetivo necesitamos la clase MovieClipLoader, veamos cómo utilizarla.

Código de inicialización

Este es código Action Script de inicialización, es decir, se ha de ejecutar una sóla vez; se debería de colocar en un fotograma clave al inicio de la película. Este código sólo necesita que exista una instancia llamada "cargador". Este cargador será un clip de película que tenga 100 fotogramas con la animación que se quiera.

// INICIAR VARIABLES
var porcentaje = 0;
var mensaje = "";

// INICIAR CARGADOR
var loader = new MovieClipLoader();
var listener = new Object();

listener.onLoadStart = function (target) {
    porcentaje = 0;
    cargador.gotoAndStop(1);
    cargador._visible = true;
}
listener.onLoadProgress = function (target, loadedBytes, totalBytes) {
    porcentaje = Math.round((loadedBytes*100)/totalBytes);
    cargador.gotoAndStop (porcentaje + 1);
}
listener.onLoadComplete = function (target) {
    mensaje = "";   
    cargador._visible = false;
}
listener.onLoadError = function (target) {
    mensaje = "error";
}
loader.addListener (listener);
cargador._visible = false;

Forma de uso

Luego, en el momento que quieras cargar una película, o una foto has de utilizar el siguiente código

loader.loadClip ("pelicula.swf", simbolo);

En este código "simbolo" es el nombre de instancia del clip de película que va a albergar la película o foto a cargar. Dónde pone "pelicula.swf" podrás poner "foto.jpg".